42 lines
1.0 KiB
Bash
42 lines
1.0 KiB
Bash
# Maintainer: Storm Dragon <storm_dragon@stormux.org>
|
|
# shellcheck disable=SC2034,SC2154
|
|
|
|
pkgname=thunderpad-git
|
|
_pkgname=thunderpad
|
|
pkgver=r159.a0f6f34
|
|
pkgrel=1
|
|
pkgdesc="Accessible joypad to keyboard and mouse mapper"
|
|
arch=('aarch64' 'x86_64')
|
|
url="https://git.stormux.org/storm/thunderpad"
|
|
license=('GPL-2.0-only')
|
|
depends=('hicolor-icon-theme' 'libx11' 'libxtst' 'qt6-base' 'systemd-libs')
|
|
makedepends=('cmake' 'git')
|
|
provides=('thunderpad')
|
|
conflicts=('thunderpad')
|
|
source=("${_pkgname}::git+https://git.stormux.org/storm/thunderpad.git")
|
|
sha256sums=('SKIP')
|
|
|
|
pkgver() {
|
|
cd "${_pkgname}" || return 1
|
|
|
|
printf 'r%s.%s' \
|
|
"$(git rev-list --count HEAD)" \
|
|
"$(git rev-parse --short=7 HEAD)"
|
|
}
|
|
|
|
build() {
|
|
cmake \
|
|
-B build \
|
|
-S "${_pkgname}" \
|
|
-DCMAKE_BUILD_TYPE=None \
|
|
-DCMAKE_INSTALL_PREFIX=/usr \
|
|
-DWITH_LIBUDEV=ON
|
|
cmake --build build
|
|
}
|
|
|
|
package() {
|
|
DESTDIR="${pkgdir}" cmake --install build
|
|
install -Dm644 "${_pkgname}/LICENSE.txt" \
|
|
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
|
|
}
|