# Maintainer: Stormux <storm_dragon@stormux.org>
# shellcheck shell=bash disable=SC2034,SC2154

pkgname=skald-git
pkgver=2026.07.08.r1.g704b1a9
pkgrel=1
pkgdesc='Audio-only hall-based conferencing server'
arch=('x86_64' 'aarch64')
url='https://git.stormux.org/storm/skald'
license=('MIT')
depends=('ffmpeg')
makedepends=('git' 'go')
provides=('skald')
conflicts=('skald')
source=(
  'git+https://git.stormux.org/storm/skald.git'
  'skald.service'
  'skald.sysusers'
  'skald.tmpfiles'
)
sha256sums=(
  'SKIP'
  '7048408e888e08c6f0751979848b85c0c5a0f0e7828b8bcf5594f7ceaf883f90'
  'd17bb4bfb320416da6e6ed43e9df8b8088f149b60808924d2dc0ac0b8e9b9a32'
  'ba8bb0933715c7eb19cdaf8d6dea4e33ff65ad676f1484f9b6a33930ec455f6e'
)

pkgver() {
  cd skald || return
  local describe
  if describe="$(git describe --long --tags --match '[0-9][0-9][0-9][0-9].[0-9][0-9].[0-9][0-9]' 2>/dev/null)"; then
    printf '%s\n' "$describe" | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
  else
    printf '2026.07.08.r%s.g%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  fi
}

build() {
  cd skald || return
  export CGO_ENABLED=0
  export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
  mkdir -p build
  go build -ldflags='-s -w' -o build/skald .
  go build -ldflags='-s -w' -o build/skaldctl ./skaldctl
}

check() {
  cd skald || return
  go test ./...
}

package() {
  cd skald || return

  install -Dm755 build/skald "$pkgdir/usr/bin/skald"
  install -Dm755 build/skaldctl "$pkgdir/usr/bin/skaldctl"

  install -d "$pkgdir/usr/share/skald/static"
  cp -a static/. "$pkgdir/usr/share/skald/static/"

  install -Dm644 README.md "$pkgdir/usr/share/doc/skald/README.md"
  install -Dm644 skald.md "$pkgdir/usr/share/doc/skald/skald.md"
  install -Dm644 skald-api.md "$pkgdir/usr/share/doc/skald/skald-api.md"
  install -Dm644 skald-client.md "$pkgdir/usr/share/doc/skald/skald-client.md"
  install -Dm644 skald-install.md "$pkgdir/usr/share/doc/skald/skald-install.md"
  install -Dm644 skald-protocol.md "$pkgdir/usr/share/doc/skald/skald-protocol.md"

  install -d "$pkgdir/var/lib/skald/data"
  install -d "$pkgdir/var/lib/skald/halls"
  install -d "$pkgdir/var/lib/skald/recordings"

  install -Dm644 "$srcdir/skald.service" "$pkgdir/usr/lib/systemd/system/skald.service"
  install -Dm644 "$srcdir/skald.sysusers" "$pkgdir/usr/lib/sysusers.d/skald.conf"
  install -Dm644 "$srcdir/skald.tmpfiles" "$pkgdir/usr/lib/tmpfiles.d/skald.conf"
}