Files

52 lines
1.4 KiB
Bash

# Maintainer: Storm Dragon <storm_dragon@stormux.org>
pkgname=navipy-git
pkgver=r17.g3ab834d
pkgrel=1
pkgdesc='Accessible Subsonic desktop client tested with Navidrome'
arch=('any')
url='https://git.stormux.org/storm/navipy'
license=('GPL-3.0-only')
depends=(
'python'
'pyside6'
'python-requests'
'python-dbus'
'python-gobject'
'qt6-multimedia'
)
makedepends=('git')
provides=('navipy')
conflicts=('navipy')
source=("navipy::git+${url}.git"
'navipy.desktop')
sha256sums=('SKIP'
'6ce7cb0a79f7f65abfafea816a6efeed246adf60c0569c85db29906faaeeb3ea')
pkgver() {
cd "$srcdir/navipy"
printf 'r%s.g%s' "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
package() {
cd "$srcdir/navipy"
# Keep the application's private src package beside its entry point.
install -Dm644 navipy.py "$pkgdir/usr/share/navipy/navipy.py"
local file
while IFS= read -r -d '' file; do
install -Dm644 "$file" "$pkgdir/usr/share/navipy/$file"
done < <(find src -type f -name '*.py' -print0)
install -Dm644 README.md "$pkgdir/usr/share/doc/navipy/README.md"
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -dm755 "$pkgdir/usr/bin" "$pkgdir/usr/share/applications"
cat > "$pkgdir/usr/bin/navipy" <<'LAUNCHER'
#!/bin/sh
exec /usr/bin/python /usr/share/navipy/navipy.py "$@"
LAUNCHER
chmod 755 "$pkgdir/usr/bin/navipy"
install -Dm644 "$srcdir/navipy.desktop" "$pkgdir/usr/share/applications/navipy.desktop"
}