# Maintainer: Storm Dragon <stormdragon2976@gmail.com>
# Maintainer: Chrys <mail@chrys.de>

_gitname='fenrir'
pkgname="${_gitname}-git"
pkgver=v0.1.2.gb72614a
pkgrel=1
pkgdesc='A user space console screen reader written in python3'
arch=('armv7h' 'i686' 'x86_64')
url='https://github.com/chrys87/${_pkgname}'
license=('MIT')
depends=('python' 'python-espeak' 'python-evdev')
optdepends=('brltty: For Braille support'
  'gstreamer: for soundicons via gstreamer'
  'sox: The default sound driver'
  'python-enchant: for spell check functionality')
makedepends=('git')
provides=('fenrir')
conflicts=('fenrir')
install="$pkgname".install
source=("git+https://github.com/chrys87/${_gitname}.git"
  'fenrir-git.install')
md5sums=('SKIP'
         '9d1e82fce2e02ae2a1216a18ca576bfb')

pkgver()
{
  cd "$srcdir/$_gitname"
  local ver="$(git describe --tags)"
  echo "${ver//-/.}"
}

package()
{
  cd "$srcdir/$_gitname"
  install -d "$pkgdir/usr/bin"
 install -d "$pkgdir/etc/fenrir/keyboard"
 install -d "$pkgdir/etc/fenrir/settings"
 install -d "$pkgdir/etc/fenrir/substitution"
 install -d "$pkgdir/usr/share/sounds/fenrir"
  install -m644 -D "autostart/systemd/fenrir.service" "$pkgdir/usr/lib/systemd/system/fenrir.service"
  python setup.py install --root="${pkgdir}/" --optimize=1
  cp -a config/keyboard/* "$pkgdir/etc/fenrir/keyboard"
  cp -a config/settings/* "$pkgdir/etc/fenrir/settings"
  cp -a config/sounds/* "$pkgdir/usr/share/sounds/fenrir"
  cp -a config/substitution/* "$pkgdir/etc/fenrir/substitution"
}

# vim: set ts=2 sw=2 et: