# Maintainer: Storm Dragon <storm_dragon@stormux.org>

pkgname=cthulhu
pkgver=2025.08.11
pkgrel=1
pkgdesc="Desktop-agnostic screen reader with plugin system, forked from Orca"
url="https://git.stormux.org/storm/cthulhu"
arch=(any)
license=(LGPL)
depends=(
  # Core AT-SPI accessibility 
  at-spi2-core
  python-atspi
  gobject-introspection-runtime
  python-gobject
  python-cairo
  gtk3
  
  # Audio and speech
  speech-dispatcher
  gstreamer
  gst-plugins-base # playbin, audiotestsrc, basic decoders
  gst-plugins-good # pulsesink, more decoders
  
  # Braille support
  brltty
  liblouis
  
  # Plugin system and D-Bus remote control
  python-pluggy
  python-dasbus
  libpeas
  
  # AI Assistant dependencies (for screenshots, HTTP requests, and actions)
  python-pillow
  python-requests
  python-pyautogui
  
  # Desktop integration
  hicolor-icon-theme
  libwnck3
  pango
  
  # System utilities
  python
  python-setproctitle
  socat # for self-voicing feature
  xorg-xkbcomp
  xorg-xmodmap
)
optdepends=(
  'espeak-ng: Alternative TTS engine'
  'festival: Alternative TTS engine' 
  'flite: Lightweight TTS engine'
  'espeak: Legacy TTS engine'
  
  # AI Assistant providers (optional)
  'claude-code: Claude AI provider support'
  'openai-codex: ChatGPT AI provider support' 
  'gemini-cli: Gemini AI provider support'
  'ollama: Local AI model support'
)
makedepends=(
  git
  meson
  ninja
  python-build
  python-installer
  python-wheel
)
source=("git+https://git.stormux.org/storm/cthulhu.git")
b2sums=('SKIP')

prepare() {
  cd cthulhu
  git checkout testing
}

pkgver() {
  cd cthulhu
  grep "^version = " src/cthulhu/cthulhuVersion.py | sed 's/version = "\(.*\)"/\1/'
}

build() {
  cd cthulhu
  arch-meson _build
  meson compile -C _build
}

package() {
  cd cthulhu
  meson install -C _build --destdir "$pkgdir"
}

# vim:set sw=2 sts=-1 et: