# Maintainer: Storm Dragon <storm_dragon@stormux.org>

pkgname=cthulhu
pkgver=2025.07.01
pkgrel=2
pkgdesc="Desktop-agnostic screen reader with plugin system, forked from Orca"
url="https://git.stormux.org/storm/cthulhu"
arch=(any)
license=(LGPL)
depends=(
  # Core AT-SPI accessibility 
  at-spi2-core
  python-atspi
  gobject-introspection-runtime
  python-gobject
  python-cairo
  gtk3
  
  # Audio and speech
  speech-dispatcher
  gstreamer
  gst-plugins-base # playbin, audiotestsrc, basic decoders
  gst-plugins-good # pulsesink, more decoders
  
  # Braille support
  brltty
  liblouis
  
  # Plugin system and D-Bus remote control
  python-pluggy
  python-dasbus
  libpeas
  
  # Desktop integration
  gsettings-desktop-schemas
  hicolor-icon-theme
  libwnck3
  pango
  
  # System utilities
  python
  python-setproctitle
  socat # for self-voicing feature
  xorg-xkbcomp
  xorg-xmodmap
)
optdepends=(
  'espeak-ng: Alternative TTS engine'
  'festival: Alternative TTS engine' 
  'flite: Lightweight TTS engine'
  'espeak: Legacy TTS engine'
)
makedepends=(
  git
)
source=("git+https://git.stormux.org/storm/cthulhu.git")
b2sums=('SKIP')

prepare() {
  cd cthulhu
  git checkout testing
  NOCONFIGURE=1 SKIP_YELP=1 ./autogen.sh
}

pkgver() {
  cd cthulhu
  grep "^version = " src/cthulhu/cthulhuVersion.py | sed 's/version = "\(.*\)"/\1/'
}

build() {
  cd cthulhu
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --disable-help
  make
}

package() {
  cd cthulhu
  make DESTDIR="$pkgdir" install
}

# vim:set sw=2 sts=-1 et: