# Maintainer: Storm Dragon <storm_dragon@stormux.org>
# shellcheck shell=bash disable=SC2034,SC2154,SC2164

pkgname=cthulhu-wine-access-git
_pkgname=cthulhu
pkgver=2026.07.18.r465.g050ae25
pkgrel=1
pkgdesc="Optional Wine and Proton accessibility bridge for Cthulhu"
url="https://git.stormux.org/storm/cthulhu"
arch=(x86_64)
license=(LGPL-2.1-or-later)
depends=(
  "cthulhu-git=${pkgver}"
  glib2
  wine
)
makedepends=(
  cmake
  git
  meson
)
provides=(cthulhu-wine-access)
conflicts=(cthulhu-wine-access)
source=("${_pkgname}::git+https://git.stormux.org/storm/${_pkgname}.git#branch=master")
sha512sums=('SKIP')
options=(!lto)

pkgver() {
  cd "${_pkgname}"
  local projectVersion revisionCount commitHash

  projectVersion=$(sed -n "s/^[[:space:]]*version: '\([^']*\)'.*/\1/p" meson.build)
  projectVersion=${projectVersion%-master}
  projectVersion=${projectVersion//-/.}
  [[ -n "${projectVersion}" ]] || return 1

  revisionCount=$(git rev-list --count HEAD)
  commitHash=$(git rev-parse --short=7 HEAD)
  printf "%s.r%s.g%s\n" "${projectVersion}" "${revisionCount}" "${commitHash}"
}

build() {
  cd "${_pkgname}"
  arch-meson _build -Dwine-access=enabled
  meson compile -C _build
}

package() {
  cd "${_pkgname}"
  install -Dm755 _build/cthulhu-wine-access.exe \
    "$pkgdir/usr/libexec/cthulhu/wine/cthulhu-wine-access.exe"
  install -Dm755 _build/cthulhu-wine-access.exe.so \
    "$pkgdir/usr/libexec/cthulhu/wine/cthulhu-wine-access.exe.so"
}

# vim:set sw=2 sts=-1 et: