# Maintainer: Storm Dragon <storm_dragon@stormux.org>

pkgname=cthulhu
pkgver=0.4
pkgrel=1
pkgdesc="Screen reader for individuals who are blind or visually impaired forked from Orca"
url="https://git.stormux.org/storm/cthulhu"
arch=(any)
license=(LGPL)
depends=(
  at-spi2-core
  brltty
  gobject-introspection-runtime
  gsettings-desktop-schemas
  gstreamer
  gst-plugins-base # playbin, audiotestsrc, basic decoders
  gst-plugins-good # pulsesink, more decoders
  gtk3
  hicolor-icon-theme
  liblouis
  libpeas
  libwnck3
  pango
  python
  python-atspi
  python-cairo
  python-gobject
  python-setproctitle
  socat
  speech-dispatcher
  xorg-xkbcomp
  xorg-xmodmap
)
makedepends=(
  git
  itstool
  yelp-tools
)
source=("git+https://git.stormux.org/storm/cthulhu.git")
b2sums=('SKIP')

prepare() {
  cd cthulhu
  NOCONFIGURE=1 ./autogen.sh
}

pkgver() {
  cd cthulhu
  grep "^version = " src/cthulhu/cthulhuVersion.py | sed 's/version = "\(.*\)"/\1/'
}

build() {
  cd cthulhu
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
  make
}

package() {
  cd cthulhu
  make DESTDIR="$pkgdir" install
}

# vim:set sw=2 sts=-1 et: