# Maintainer: Storm Dragon <storm_dragon@stormux.org>
# shellcheck shell=bash disable=SC2034,SC2154,SC2164

pkgname=cthulhu-wine-access
pkgver=2026.09.09
pkgrel=1
pkgdesc="Optional Wine and Proton accessibility bridge for Cthulhu"
url="https://git.stormux.org/storm/cthulhu"
arch=(x86_64)
license=(LGPL-2.1-or-later)
depends=(
  glib2
  wine
)
makedepends=(
  cmake
  git
)
source=("git+https://git.stormux.org/storm/cthulhu.git#tag=${pkgver}")
sha512sums=('SKIP')
options=(!lto !debug)

build() {
  local sourceDir="${srcdir}/cthulhu"
  bash "${sourceDir}/scripts/build-wine-access.sh" \
    "${sourceDir}/wine-access" \
    "${sourceDir}/_build/wine-access-build" \
    "${sourceDir}/_build/cthulhu-wine-access.exe" \
    "${sourceDir}/_build/cthulhu-wine-access.exe.so"
}

package() {
  cd cthulhu
  install -Dm755 _build/cthulhu-wine-access.exe \
    "$pkgdir/usr/libexec/cthulhu/wine/cthulhu-wine-access.exe"
  install -Dm755 _build/cthulhu-wine-access.exe.so \
    "$pkgdir/usr/libexec/cthulhu/wine/cthulhu-wine-access.exe.so"
}

# vim:set sw=2 sts=-1 et: