diff --git a/distro-packages/Arch-Linux/cthulhu-git/.SRCINFO b/distro-packages/Arch-Linux/cthulhu-git/.SRCINFO
deleted file mode 100644
index efafa99..0000000
--- a/distro-packages/Arch-Linux/cthulhu-git/.SRCINFO
+++ /dev/null
@@ -1,43 +0,0 @@
-pkgbase = cthulhu-git
-	pkgdesc = Desktop-agnostic screen reader with speech, Braille, and Tentacle support
-	pkgver = 2026.10.14.r3.ge5049b9
-	pkgrel = 1
-	url = https://git.stormux.org/storm/cthulhu
-	arch = x86_64
-	arch = aarch64
-	arch = armv7h
-	license = GPL-3.0-or-later
-	makedepends = git
-	makedepends = go
-	makedepends = pkgconf
-	depends = glibc
-	depends = at-spi2-core
-	depends = glib2
-	depends = gdk-pixbuf2
-	depends = gtk3
-	depends = speech-dispatcher
-	depends = gstreamer
-	depends = gst-plugins-base
-	depends = gst-plugins-good
-	depends = brltty
-	depends = liblouis
-	depends = libx11
-	depends = libxres
-	depends = libxtst
-	depends = libxfixes
-	depends = libxkbcommon
-	depends = xclip
-	depends = dbus
-	depends = systemd
-	optdepends = git: Discover and update Tentacle repositories
-	optdepends = tesseract: OCR engine for text recognition
-	optdepends = tesseract-data-eng: English OCR language data
-	provides = cthulhu=2026.10.14.r3.ge5049b9
-	conflicts = cthulhu
-	options = !debug
-	options = !lto
-	source = cthulhu::git+https://git.stormux.org/storm/cthulhu.git#branch=master
-	sha512sums = SKIP
-	optdepends_x86_64 = wine-access: Wine, Proton, NVDA Controller, and Tolk integration
-
-pkgname = cthulhu-git
diff --git a/distro-packages/Arch-Linux/cthulhu/.gitignore b/distro-packages/Arch-Linux/cthulhu/.gitignore
new file mode 100644
index 0000000..0d03072
--- /dev/null
+++ b/distro-packages/Arch-Linux/cthulhu/.gitignore
@@ -0,0 +1,3 @@
+/src/
+/pkg/
+/cthulhu/
diff --git a/distro-packages/Arch-Linux/cthulhu/PKGBUILD b/distro-packages/Arch-Linux/cthulhu/PKGBUILD
new file mode 100644
index 0000000..9a7e960
--- /dev/null
+++ b/distro-packages/Arch-Linux/cthulhu/PKGBUILD
@@ -0,0 +1,90 @@
+# Maintainer: Storm Dragon <storm_dragon@stormux.org>
+# shellcheck shell=bash disable=SC2034,SC2154,SC2164
+
+pkgname=cthulhu
+pkgver=2026.10.31
+pkgrel=1
+pkgdesc="Desktop-agnostic screen reader with speech, Braille, and Tentacle support"
+url="https://git.stormux.org/storm/cthulhu"
+arch=(x86_64 aarch64 armv7h)
+license=(GPL-3.0-or-later)
+conflicts=(cthulhu-git)
+depends=(
+  # Native accessibility and user interface
+  glibc
+  at-spi2-core
+  glib2
+  gdk-pixbuf2
+  gtk3
+  # Audio and speech
+  speech-dispatcher
+  gstreamer
+  gst-plugins-base # playbin, audiotestsrc, basic decoders
+  gst-plugins-good # pulsesink, more decoders
+
+  # Braille support
+  brltty
+  liblouis
+
+  # Xorg input, window capture, and clipboard operations
+  libx11
+  libxres
+  libxtst
+  libxfixes
+  libxkbcommon
+  xclip
+
+  # Private D-Bus services
+  dbus
+)
+optdepends=(
+  'git: Discover and update Tentacle repositories'
+  'tesseract: OCR engine for text recognition'
+  'tesseract-data-eng: English OCR language data'
+)
+optdepends_x86_64=(
+  # Wine accessibility helpers are supported on x86_64.
+  'wine-access: Wine, Proton, NVDA Controller, and Tolk integration'
+)
+makedepends=(
+  git
+  go
+  pkgconf
+)
+options=(!debug !lto)
+# The release tag must exist upstream before makepkg can fetch this source.
+source=("${pkgname}::git+https://git.stormux.org/storm/${pkgname}.git#tag=${pkgver}")
+sha512sums=('SKIP')
+
+build() {
+  cd "${pkgname}"
+  export CGO_ENABLED=1
+  export CGO_CPPFLAGS="${CPPFLAGS}"
+  export CGO_CFLAGS="${CFLAGS}"
+  export CGO_CXXFLAGS="${CXXFLAGS}"
+  export CGO_LDFLAGS="${LDFLAGS}"
+  export GOPATH="${srcdir}/go"
+  export GOCACHE="${GOCACHE:-${srcdir}/go-build}"
+  export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
+
+  go build -o build/cthulhu ./cmd/cthulhu
+  go build -tags brlapi -o build/cthulhu-braille ./cmd/cthulhu-braille
+}
+
+check() {
+  cd "${pkgname}"
+  export CGO_ENABLED=1
+  export GOPATH="${srcdir}/go"
+  export GOCACHE="${GOCACHE:-${srcdir}/go-build}"
+  go test -tags brlapi ./... -count=1
+}
+
+package() {
+  cd "${pkgname}"
+  install -Dm755 build/cthulhu "${pkgdir}/usr/bin/cthulhu"
+  install -Dm755 build/cthulhu-braille "${pkgdir}/usr/bin/cthulhu-braille"
+  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  install -Dm644 AUTHORS "${pkgdir}/usr/share/doc/${pkgname}/AUTHORS"
+}
+
+# vim:set sw=2 sts=-1 et:
diff --git a/internal/version/version.go b/internal/version/version.go
index dfb1f2d..9b6bf37 100644
--- a/internal/version/version.go
+++ b/internal/version/version.go
@@ -21,7 +21,7 @@ import "strings"
 
 const Name = "Cthulhu"
 
-const Version = "2026.10.30"
+const Version = "2026.10.31"
 const Channel = "master"
 
 var Build = Version